MICHELANGELO SMART GATE

#include "thingProperties.h"

const int pinRPWM = 5;
const int pinLPWM = 6;
const int pinFotocellula1 = A1;
const int pinFotocellula2 = A2;
const int pinFinecorsaApertura = 8;
const int pinFinecorsaChiusura = 9;
const int pinLed = 10;

const int sogliaFotocellula = 600;
const unsigned long tempoAutochiusura = 30000;
unsigned long istanteAperturaCompleta = 0;
bool autochiusuraAttiva = false;

void setup() {
  pinMode(pinRPWM, OUTPUT);
  pinMode(pinLPWM, OUTPUT);
  pinMode(pinLed, OUTPUT);
  pinMode(pinFinecorsaApertura, INPUT_PULLUP);
  pinMode(pinFinecorsaChiusura, INPUT_PULLUP);
  initProperties();
  ArduinoCloud.begin(ArduinoIoTPreferredConnection);
  fermaMotore();
}

void loop() {
  ArduinoCloud.update();

  if (stopMotore) {
    fermaMotore();
    autochiusuraAttiva = false;
    apri = false;
    chiudi = false;
    stopMotore = false;
  }

  if (resetCancello) {
    aggiornaStatoDaFinecorsa();
    resetCancello = false;
  }

  if (apri) apriCancello();
  if (chiudi) chiudiCancello();

  if (autochiusuraAttiva && millis() - istanteAperturaCompleta >= tempoAutochiusura) {
    if (!ostacoloPresente()) chiudiCancello();
  }

  aggiornaLampeggiante();
}

void apriCancello() {
  if (digitalRead(pinFinecorsaApertura) == LOW) {
    fermaMotore();
    statoCancello = "Aperto";
    istanteAperturaCompleta = millis();
    autochiusuraAttiva = true;
    apri = false;
    return;
  }
  analogWrite(pinRPWM, 180);
  analogWrite(pinLPWM, 0);
  statoCancello = "In apertura";
}

void chiudiCancello() {
  if (ostacoloPresente()) {
    fermaMotore();
    delay(500);
    apriCancello();
    return;
  }
  if (digitalRead(pinFinecorsaChiusura) == LOW) {
    fermaMotore();
    statoCancello = "Chiuso";
    chiudi = false;
    return;
  }
  analogWrite(pinRPWM, 0);
  analogWrite(pinLPWM, 180);
  statoCancello = "In chiusura";
}

bool ostacoloPresente() {
  return analogRead(pinFotocellula1) > sogliaFotocellula ||
         analogRead(pinFotocellula2) > sogliaFotocellula;
}

void fermaMotore() {
  analogWrite(pinRPWM, 0);
  analogWrite(pinLPWM, 0);
  digitalWrite(pinLed, LOW);
  statoCancello = "Fermo";
}

void aggiornaStatoDaFinecorsa() {
  if (digitalRead(pinFinecorsaApertura) == LOW) statoCancello = "Aperto";
  else if (digitalRead(pinFinecorsaChiusura) == LOW) statoCancello = "Chiuso";
  else statoCancello = "Fermo";
}

void aggiornaLampeggiante() {
  static unsigned long ultimoCambio = 0;
  static bool acceso = false;
  if (statoCancello == "In apertura" || statoCancello == "In chiusura") {
    if (millis() - ultimoCambio >= 400) {
      ultimoCambio = millis();
      acceso = !acceso;
      digitalWrite(pinLed, acceso);
    }
  }
}